prototype(Newland.CityTheme:GridTeaser) < prototype(Neos.Neos:Content) {
    templatePath = 'resource://Newland.CityTheme/Private/Templates/NodeTypes/GridTeaser.html'

    link = ${q(node).property('link')}
    link.@process.convertUris = Neos.Neos:ConvertUris

    linkTarget = '_blank'
    linkTarget.@if.external = ${String.indexOf(q(node).property('link'), 'node://') == -1}

    // Wrap GridTeaser width appropirate grid item markup and set selected width
    @process.wrapTeaser = ${'<div class="o-grid__item ' + q(node).property('size') +'">' + value + '</div>'}

    gridTeaserSilhouette = ${q(site).property('gridTeaserSilhouette')}

    focusPoint = ${q(node).property('focusPoint')}

    toplineIsUppercase = ${q(node).property('toplineIsUppercase')}

    imageMaximumWidth = Neos.Fusion:Case {
        isGridItemBig {
            condition = ${q(node).property('size') == 'o-grid__item--3/3'}
            renderer = 1136
        }
        fallback {
            condition = TRUE
            renderer = 640
        }
    }

    alternativeText = Neos.Fusion:Case {
        isImagePropertyCaption {
            condition = ${!String.isBlank(q(node).property('image').caption)}
            renderer = ${String.trim(String.stripTags(q(node).property('image').caption))}
        }
        fallback {
            condition = TRUE
            renderer = ${q(node).property('image').title}
        }
    }
}
